PRINT X

INCREASE N INCREASE N INCREASE N INCREASE N INCREASE N
REPEAT N TIMES ( INCREASE N INCREASE N INCREASE N INCREASE N )
REPEAT N TIMES ( INCREASE N INCREASE N INCREASE N INCREASE N )

INCREASE B
INCREASE I			# IF X == 1
CLEAR Y
INCREASE Y
REPEAT X TIMES (
	REPEAT Y TIMES (		# Y = X < 2
		INCREASE J
		REPEAT I TIMES (
			CLEAR J
		)
		REPEAT J TIMES (
			CLEAR Y
		)
		CLEAR I
		CLEAR J
	)
)
REPEAT Y TIMES (
	CLEAR B
)
CLEAR Y				# ENDIF X == 1
REPEAT B TIMES (
REPEAT N TIMES (			# MASTER LOOP
REPEAT B TIMES (			# IF break
	INCREASE C
	REPEAT X TIMES (		# DIV start
		REPEAT C TIMES (
			CLEAR X
			CLEAR C
		)
		INCREASE J
		REPEAT I TIMES (
			CLEAR I
			INCREASE X
			CLEAR O		# Mark as odd
			CLEAR J
		)
		REPEAT J TIMES (
			INCREASE I
			INCREASE O	# Mark as even
			CLEAR J
		)
	)				# DIV end
	CLEAR I				# Outputs:
					# - X floor(X/2)
					# - O if odd

	INCREASE E					# IF odd
	REPEAT O TIMES (
		REPEAT X TIMES (
			INCREASE X
			INCREASE X
		)
		INCREASE X
		INCREASE X
		REPEAT X TIMES (
			INCREASE T
			INCREASE T
		)
		PRINT T
		CLEAR T
		CLEAR E
		CLEAR Y
	)
	REPEAT E TIMES (				# ELSE
		INCREASE I					# IF X == 1
		CLEAR Y
		INCREASE Y
		REPEAT X TIMES (					# Y = X < 2
			REPEAT Y TIMES (
				INCREASE J
				REPEAT I TIMES (
					CLEAR J
				)
				REPEAT J TIMES (
					CLEAR Y
				)
				CLEAR I
				CLEAR J
			)
		)
		REPEAT Y TIMES (
			CLEAR B
		)
		CLEAR Y						# ENDIF X == 1
		CLEAR E
	)						# ENDIF odd
	CLEAR O

	PRINT X
)				# ENDIF break
)				# END MASTER LOOP
)