# Assign big num for loop (1000)
INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A INCREASE A
REPEAT A TIMES (
REPEAT A TIMES (
REPEAT A TIMES (
INCREASE L
)
)
)
CLEAR A
# I: bool - is iteration ongoing (hasn't reached 1 and should still iterate)
INCREASE I
REPEAT L TIMES (
REPEAT I TIMES (
# Print number of the series
PRINT X
# calculate halved X to E and find out if X is even in E
CLEAR H # halved value
CLEAR E # is even
CLEAR A # current iter is uneven
CLEAR B INCREASE B # current iter is even
REPEAT X TIMES (
# increment accumulation H if iteration is even
REPEAT A TIMES (
INCREASE H
INCREASE E
)
REPEAT B TIMES (
CLEAR E
)
# flip A and B
# move A to C
CLEAR C REPEAT A TIMES ( INCREASE C )
# move B to A
CLEAR A REPEAT B TIMES ( INCREASE A )
# move C to B
CLEAR B REPEAT C TIMES ( INCREASE B )
)
# if X is even: move H value to X
REPEAT E TIMES ( CLEAR X REPEAT H TIMES ( INCREASE X ) )
# get not of E
CLEAR F INCREASE F REPEAT E TIMES ( CLEAR F )
# if x in not even (F):
REPEAT F TIMES (
REPEAT X TIMES (
INCREASE X
INCREASE X
)
INCREASE X
)
)
# check: do we keep iterating (is x > 1)
CLEAR I
CLEAR A
REPEAT X TIMES (
# if A is true: set I to true
REPEAT A TIMES (
CLEAR I INCREASE I
)
# set A to true
CLEAR A INCREASE A
)
)
INCREASE S
PRINT S